Информация о счёте

Функции клиентского терминала и проверки состояния удобно применять, например, для ограничения использования программ при коммерческом распространении. Рассмотрим, как может быть решена такая задача:

Задача 39. Представить защитный код программы, распространяемой на коммерческой основе, удовлетворяющий следующим требованиям: для исполнения программы на реальных счетах индивидуальных клиентов требуется ввести пароль; для исполнения программы на реальных счетах корпоративных клиентов пароль не требуется; ограничения при исполнении программы на демо-счёте не предусмотрены.

В этом примере правильно сформулирована постановка задачи. Для успешного коммерческого распространения в распоряжение потенциальных потребителей необходимо предоставить программу, которая в полной мере может быть опробована на демо-счёте. При этом пользователь может оценить все достоинства программы и принять решение о её приобретении.

Применять один общий пароль для всех клиентов неправильно - в этом случае появляется риск несанкционированного распространения программы. Поэтому для индивидуальных клиентов пароль должен быть поставлен в зависимость от номера реального счёта. Для корпоративных клиентов (если дилинговый центр приобрёл лицензию для всех своих трейдеров) использовать пароль нет необходимости - программа должна сама определить, к какому серверу подключён клиентский терминал. И если это сервер корпоративного клиента, то необходимо предоставить любому пользователю возможность беспрепятственной работы.

Решение Задачи 39 для ограничения прав использования программ может быть таким (эксперт сheck.mq4):

//--------------------------------------------------------------------
// сheck.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------- 1 --
extern int Parol=12345;
//--------------------------------------------------------------- 2 --
int start()                            // Спец. функция start
  {
   if(Check()==false)                  // Если условия использования..
      return;                          // ..не выполняются, то выход
 
   // Здесь должен быть указан основной код программы
   Alert("Исполнение программы");      // Алерт для примера
 
   return;                             // Выход из start()
  }
//--------------------------------------------------------------- 3 --
bool Check()                           // Пользов. функция проверки ..
  {                                    // .. условий использования
   if (IsDemo()==true)                 // Если это демо-счёт, то..
      return(true);                    // .. других ограничений нет
   if (AccountCompany()=="SuperBank")  // Для корпоративных клиентов..
      return(true);                    // ..пароль не нужен
   int Key=AccountNumber()*2+1000001;  // Вычисляем ключ 
   if (Parol==Key)                     // Если пароль верный, то..
      return(true);                    // ..разрешаем работу на реале
   Alert("Неправильный пароль. Эксперт не работает.");
   return(false);                      // Выход из пользов. функции
  }
//--------------------------------------------------------------- 4 --

В данном примере необходимая проверка выполняется в первых строках специальной функции start (блок 2-3):

   if(Check()==false)                  // Если условия использования..

Если в результате выполнения проверки пользовательская функция Check() (блок 3-4) вернула false, то управление передаётся на оператор return и специальная функция start() заканчивает работу. Основной код программы располагается непосредственно после указанной проверки. В результате успешной проверки функция Check() вернёт true, в этом случае основной код программы будет исполнен.

В пользовательской функции Check() выполняется проверка по трём критериям:
- является ли счёт демонстрационным;
- принадлежит ли сервер корпоративному клиенту;
- подходит ли пароль к реальному счёту.

Для проверки по первому критерию используется функция IsDemo().

Функция IsDemo()

bool IsDemo()

Функция возвращает TRUE, если программа работает на демонстрационном счете, в противном случае возвращает FALSE.

Если функция IsDemo() возвращает true, то пользователь работает на демо-счёте. Это значит, что выполнять другие проверки нет необходимости (т.к. опробование программы на демо-счёте позволено для всех желающих). В этом случае функция Check() прекращает работу, и возвращает значение true:

   if (IsDemo() == true)               // Если это демо-счёт, то..
      return(true);                    // .. других ограничений нет

Если же в функция IsDemo() вернёт значение false, значит, пользователь работает на реальном счёте. В этом случае необходимо выяснить, достаточно ли у пользователя прав. В данном примере сначала выполняется проверка корпоративных клиентов, для этого используется функция AccountCompany().

Функция AccountCompany()

 string AccountCompany()

Функция возвращает название брокерской компании, в которой зарегистрирован текущий счет.

Если в результате выполнения проверки:

   if (AccountCompany() == "SuperBank")// Для корпоративных клиентов..
      return(true);                    // ..пароль не нужен

установлено, что название компании совпадает с тем, что указано в программе, то функция Check() закончит работу и вернёт true - проверка закончена успешно. Если же оказывается, что клиент подключен к другой компании (не являющейся корпоративным клиентом), то необходимо выяснить имеет ли он индивидуальную лицензию.

В строке:

   int Key = AccountNumber()*2+1000001;// Вычисляем ключ

в программу заложен алгоритм вычисления ключа для любого номера счёта. В данном примере это простой способ. Программист по своему усмотрению может ввести в программу другой, более сложный способ вычисления ключа. В любом случае алгоритм вычисления ключа должен учитывать номер счёта, который доступен программе через функцию AccountNumber().

Функция AccountNumber()

 int AccountNumber()

Функция возвращает номер текущего счета.

Ранее вычисленный по тому же алгоритму пароль передаётся пользователю. Если в результате проверки оказывается, что пароль и ключ совпадают, то функция Check() прекращает работу и возвращает значение true:

   if (Parol == Key)                   // Если пароль верный, то..
      return(true);                    // ..разрешаем работу на реале

Если ни одна из проверок не закончилась успешно, это означает, что пользователь не имеет права применения данной программы на реальном счёте. В этом случае, после соответствующего уведомления, функция Check() прекращает работу и возвращает значение false. Таким образом пресекается попытка несанкционированного использования программы.

Функции, возвращающие информацию о клиентском терминале

Функции, позволяющие определить текущее состояние клиентского терминала, в том числе состояние окружения выполняемой MQL4-программы

Функции для доступа к информации об активном счете

Для получения подробного описания этих и других функций необходимо обратиться к справочной документации на MQL4.community, сайте MetaQuotes Ltd. или к разделу "Справка" в редакторе MetaEditor.